开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
keyboard.S
资源名称：kernel.rar　[点击查看]
上传用户：qyj398
上传日期：2008-02-19
资源大小：71k
文件大小：17k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

keyboard.S：源码内容
  1. /*
  2.  *  linux/kernel/keyboard.S
  3.  *
  4.  *  (C) 1991  Linus Torvalds
  5.  */
  7. /*
  8.  * Thanks to Alfred Leung for US keyboard patches
  9.  * Wolfgang Thiel for German keyboard patches
  10.  * Marc Corsini for the French keyboard
  11.  * LeBlanc@mcc.ac.uk for the UK keyboard
  12.  * Tommy Thorn (tthorn@daimi.aau.dk) for Danish keyboard
  13.  */
  15. /* KBD_FINNISH for Finnish keyboards
  16.  * KBD_US for US-type
  17.  * KBD_GR for German keyboards
  18.  * KBD_FR for Frech keyboard
  19.  * KBD_UK for British extended keyboard
  20.  * KBD_DK for Danish keyboard
  21.  */
  22. #define KBD_FINNISH
  24. .text
  25. .globl _hard_reset_now
  26. .globl _keyboard_interrupt
  27. .globl _kapplic
  28. .globl _kmode
  29. .globl _kleds
  30. .globl _set_leds
  32. /*
  33.  * these are for the keyboard read functions
  34.  */
  35. size = 1024 /* must be a power of two ! And MUST be the same
  36.    as in tty_io.c !!!! */
  37. head = 4
  38. tail = 8
  39. proc_list = 12
  40. buf = 16
  42. _kapplic: .byte 0
  43. _kmode: .byte 0 /* caps, alt, ctrl and shift mode */
  44. _kleds: .byte 2 /* num-lock, caps, scroll-lock mode (nom-lock on) */
  45. e0: .byte 0
  47. /*
  48.  *  con_int is the real interrupt routine that reads the
  49.  *  keyboard scan-code and converts it into the appropriate
  50.  *  ascii character(s).
  51.  */
  52. _keyboard_interrupt:
  53. cld
  54. pushl %eax
  55. pushl %ebx
  56. pushl %ecx
  57. pushl %edx
  58. push %ds
  59. push %es
  60. movl $0x10,%eax
  61. mov %ax,%ds
  62. mov %ax,%es
  63. xorl %eax,%eax /* %eax is scan code */
  64. inb $0x60,%al
  65. pushl %eax
  66. inb $0x61,%al
  67. jmp 1f
  68. 1: jmp 1f
  69. 1: orb $0x80,%al
  70. jmp 1f
  71. 1: jmp 1f
  72. 1: outb %al,$0x61
  73. jmp 1f
  74. 1: jmp 1f
  75. 1: andb $0x7F,%al
  76. outb %al,$0x61
  77. jmp 1f
  78. 1: jmp 1f
  79. 1: movb $0x20,%al
  80. outb %al,$0x20
  81. popl %eax
  82. movl $1,%ebx
  83. cmpb $0xE0,%al
  84. je end_intr
  85. movl $2,%ebx
  86. cmpb $0xE1,%al
  87. je end_intr
  88. sti
  89. call key_table(,%eax,4)
  90. call _do_keyboard_interrupt
  91. movl $0,%ebx
  92. end_intr:
  93. movb %bl,e0
  94. pop %es
  95. pop %ds
  96. popl %edx
  97. popl %ecx
  98. popl %ebx
  99. popl %eax
  100. iret
  102. /*
  103.  * This routine fills the buffer with max 8 bytes, taken from
  104.  * %ebx:%eax. (%edx is high). The bytes are written in the
  105.  * order %al,%ah,%eal,%eah,%bl,%bh ... until %eax is zero.
  106.  */
  107. put_queue:
  108. pushl %ecx
  109. pushl %edx
  110. movl _table_list,%edx # read-queue for console
  111. movl head(%edx),%ecx
  112. 1: movb %al,buf(%edx,%ecx)
  113. incl %ecx
  114. andl $size-1,%ecx
  115. cmpl tail(%edx),%ecx # buffer full - discard everything
  116. je 3f
  117. shrdl $8,%ebx,%eax
  118. je 2f
  119. shrl $8,%ebx
  120. jmp 1b
  121. 2: movl %ecx,head(%edx)
  122. movl proc_list(%edx),%ecx
  123. testl %ecx,%ecx
  124. je 3f
  125. movl $0,(%ecx)
  126. 3: popl %edx
  127. popl %ecx
  128. ret
  130. ctrl: movb $0x04,%al
  131. jmp 1f
  132. alt: movb $0x10,%al
  133. 1: cmpb $0,e0
  134. je 2f
  135. addb %al,%al
  136. 2: orb %al,_kmode
  137. ret
  138. unctrl: movb $0x04,%al
  139. jmp 1f
  140. unalt: movb $0x10,%al
  141. 1: cmpb $0,e0
  142. je 2f
  143. addb %al,%al
  144. 2: notb %al
  145. andb %al,_kmode
  146. ret
  148. lshift:
  149. orb $0x01,_kmode
  150. ret
  151. unlshift:
  152. andb $0xfe,_kmode
  153. ret
  154. rshift:
  155. orb $0x02,_kmode
  156. ret
  157. unrshift:
  158. andb $0xfd,_kmode
  159. ret
  161. old_leds:
  162. .byte 2
  164. caps: testb $0x80,_kmode
  165. jne 1f
  166. xorb $4,_kleds
  167. xorb $0x40,_kmode
  168. orb $0x80,_kmode
  169. _set_leds:
  170. movb _kleds,%al
  171. cmpb old_leds,%al
  172. je 1f
  173. movb %al,old_leds
  174. call kb_wait
  175. movb $0xed,%al /* set leds command */
  176. outb %al,$0x60
  177. call kb_wait
  178. movb _kleds,%al
  179. outb %al,$0x60
  180. 1: ret
  181. uncaps: andb $0x7f,_kmode
  182. ret
  183. scroll:
  184. testb $0x03,_kmode
  185. je 1f
  186. call _show_mem
  187. jmp 2f
  188. 1: call _show_state
  189. 2: xorb $1,_kleds
  190. jmp _set_leds
  192. num: cmpb $0x01,_kapplic
  193. jne notappl
  194. movw $0x0050,%ax
  195. applkey:
  196. shll $16,%eax
  197. movw $0x4f1b,%ax
  198. xorl %ebx,%ebx
  199. jmp put_queue
  200.  
  201. notappl:
  202. xorb $2,_kleds
  203. jmp _set_leds
  205. /*
  206.  *  cursor-key/numeric keypad cursor keys are handled here.
  207.  *  checking for numeric keypad etc.
  208.  */
  209. cursor:
  210. subb $0x47,%al
  211. jb 1f
  212. cmpb $12,%al
  213. ja 1f
  214. jne cur2 /* check for ctrl-alt-del */
  215. testb $0x0c,_kmode
  216. je cur2
  217. testb $0x30,_kmode
  218. jne _ctrl_alt_del
  219. cur2: cmpb $0x01,e0 /* e0 forces cursor movement */
  220. je cur
  221. testb $0x03,_kmode /* shift forces cursor */
  222. jne cur
  223. cmpb $0x01,_kapplic
  224. jne notcappl
  225. movb appl_table(%eax),%al
  226. jmp applkey
  227. notcappl:
  228. testb $0x02,_kleds /* not num-lock forces cursor */
  229. je cur
  230. xorl %ebx,%ebx
  231. movb num_table(%eax),%al
  232. jmp put_queue
  233. 1: ret
  235. /*
  236.  * cursor keys send ^[ [ x if normal, ^[ O x if application mode
  237.  */
  238. cur: movb cur_table(%eax),%al
  239. cmpb $'9,%al
  240. ja ok_cur
  241. movb $'~,%ah
  242. ok_cur: shll $16,%eax
  243. movw $0x5b1b,%ax
  244. xorl %ebx,%ebx
  245. cmpb $0x01,_kapplic
  246. jne put_queue
  247. movb $0x4f,%ah
  248. jmp put_queue
  250. #if defined(KBD_FR) /* || defined(KBD_DK) correct, but .. */
  251. num_table:
  252. .ascii "789-456+1230."
  253. #else
  254. num_table:
  255. .ascii "789-456+1230,"
  256. #endif
  257. cur_table:
  258. .ascii "HA5-DGC+YB623"
  260. /*
  261.     Keypad /          35 B7 Q
  262.     Keypad *  (PrtSc) 37 B7 R
  263.     Keypad NumLock      45 ?? P
  264.     Keypad 7  (Home) 47 C7 w
  265.     Keypad 8  (Up arrow) 48 C8 x
  266.     Keypad 9  (PgUp) 49 C9 y
  267.     Keypad - 4A CA S
  268.     Keypad 4  (Left arrow) 4B CB t
  269.     Keypad 5 4C CC u
  270.     Keypad 6  (Right arrow) 4D CD v
  271.     Keypad + 4E CE l
  272.     Keypad 1  (End)  4F CF q
  273.     Keypad 2  (Down arrow) 50 D0 r
  274.     Keypad 3  (PgDn) 51 D1 s
  275.     Keypad 0  (Ins) 52 D2 p
  276.     Keypad .  (Del)  53 D3 n
  277. */    
  278.  
  279. appl_table:
  280. .ascii "wxyStuvlqrspn"
  282. /*
  283.  * this routine handles function keys
  284.  */
  285. func:
  286. subb $0x3B,%al
  287. jb end_func
  288. cmpb $9,%al
  289. jbe ok_func
  290. subb $18,%al
  291. cmpb $10,%al
  292. jb end_func
  293. cmpb $11,%al
  294. ja end_func
  295. ok_func:
  296. testb $0x10,_kmode
  297. jne alt_func
  298. cmpl $4,%ecx /* check that there is enough room */
  299. jl end_func
  300. movl func_table(,%eax,4),%eax
  301. xorl %ebx,%ebx
  302. jmp put_queue
  303. alt_func:
  304. pushl %eax
  305. call _change_console
  306. popl %eax
  307. end_func:
  308. ret
  310. /*
  311.  * function keys send F1:'esc [ [ A' F2:'esc [ [ B' etc.
  312.  */
  313. func_table:
  314. .long 0x415b5b1b,0x425b5b1b,0x435b5b1b,0x445b5b1b
  315. .long 0x455b5b1b,0x465b5b1b,0x475b5b1b,0x485b5b1b
  316. .long 0x495b5b1b,0x4a5b5b1b,0x4b5b5b1b,0x4c5b5b1b
  318. #if defined(KBD_FINNISH)
  319. key_map:
  320. .byte 0,27
  321. .ascii "1234567890+'"
  322. .byte 127,9
  323. .ascii "qwertyuiop}"
  324. .byte 0,13,0
  325. .ascii "asdfghjkl|{"
  326. .byte 0,0
  327. .ascii "'zxcvbnm,.-"
  328. .byte 0,'*,0,32 /* 36-39 */
  329. .fill 16,1,0 /* 3A-49 */
  330. .byte '-,0,0,0,'+ /* 4A-4E */
  331. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  332. .byte '<
  333. .fill 10,1,0
  335. shift_map:
  336. .byte 0,27
  337. .ascii "!"#$%&/()=?`"
  338. .byte 127,9
  339. .ascii "QWERTYUIOP]^"
  340. .byte 13,0
  341. .ascii "ASDFGHJKL\["
  342. .byte 0,0
  343. .ascii "*ZXCVBNM;:_"
  344. .byte 0,'*,0,32 /* 36-39 */
  345. .fill 16,1,0 /* 3A-49 */
  346. .byte '-,0,0,0,'+ /* 4A-4E */
  347. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  348. .byte '>
  349. .fill 10,1,0
  351. alt_map:
  352. .byte 0,0
  353. .ascii "@${[]}\"
  354. .byte 0,0
  355. .byte 0,0,0,0,0,0,0,0,0,0,0
  356. .byte '~,13,0
  357. .byte 0,0,0,0,0,0,0,0,0,0,0
  358. .byte 0,0
  359. .byte 0,0,0,0,0,0,0,0,0,0,0
  360. .byte 0,0,0,0 /* 36-39 */
  361. .fill 16,1,0 /* 3A-49 */
  362. .byte 0,0,0,0,0 /* 4A-4E */
  363. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  364. .byte '|
  365. .fill 10,1,0
  367. #elif defined(KBD_US)
  369. key_map:
  370. .byte 0,27
  371. .ascii "1234567890-="
  372. .byte 127,9
  373. .ascii "qwertyuiop[]"
  374. .byte 13,0
  375. .ascii "asdfghjkl;'"
  376. .byte '`,0
  377. .ascii "\zxcvbnm,./"
  378. .byte 0,'*,0,32 /* 36-39 */
  379. .fill 16,1,0 /* 3A-49 */
  380. .byte '-,0,0,0,'+ /* 4A-4E */
  381. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  382. .byte '<
  383. .fill 10,1,0
  385. shift_map:
  386. .byte 0,27
  387. .ascii "!@#$%^&*()_+"
  388. .byte 127,9
  389. .ascii "QWERTYUIOP{}"
  390. .byte 13,0
  391. .ascii "ASDFGHJKL:""
  392. .byte '~,0
  393. .ascii "|ZXCVBNM<>?"
  394. .byte 0,'*,0,32 /* 36-39 */
  395. .fill 16,1,0 /* 3A-49 */
  396. .byte '-,0,0,0,'+ /* 4A-4E */
  397. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  398. .byte '>
  399. .fill 10,1,0
  401. alt_map:
  402. .byte 0,0
  403. .ascii "@${[]}\"
  404. .byte 0,0
  405. .byte 0,0,0,0,0,0,0,0,0,0,0
  406. .byte '~,13,0
  407. .byte 0,0,0,0,0,0,0,0,0,0,0
  408. .byte 0,0
  409. .byte 0,0,0,0,0,0,0,0,0,0,0
  410. .byte 0,0,0,0 /* 36-39 */
  411. .fill 16,1,0 /* 3A-49 */
  412. .byte 0,0,0,0,0 /* 4A-4E */
  413. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  414. .byte '|
  415. .fill 10,1,0
  417. #elif defined(KBD_UK)
  419. key_map:
  420. .byte 0,27
  421. .ascii "1234567890-="
  422. .byte 127,9
  423. .ascii "qwertyuiop[]"
  424. .byte 13,0
  425. .ascii "asdfghjkl;'"
  426. .byte '`,0
  427. .ascii "#zxcvbnm,./"
  428. .byte 0,'*,0,32 /* 36-39 */
  429. .fill 16,1,0 /* 3A-49 */
  430. .byte '-,0,0,0,'+ /* 4A-4E */
  431. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  432. .ascii "\"
  433. .fill 10,1,0
  435. shift_map:
  436. .byte 0,27
  437. .ascii "!"#$%%&*()_+"
  438. .byte 127,9
  439. .ascii "QWERTYUIOP{}"
  440. .byte 13,0
  441. .ascii "ASDFGHJKL:@"
  442. .byte '~,0
  443. .ascii "~ZXCVBNM<>?"
  444. .byte 0,'*,0,32 /* 36-39 */
  445. .fill 16,1,0 /* 3A-49 */
  446. .byte '-,0,0,0,'+ /* 4A-4E */
  447. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  448. .byte '|
  449. .fill 10,1,0
  451. alt_map:
  452. .byte 0,0
  453. .ascii "@${[]}\"
  454. .byte 0,0
  455. .byte 0,0,0,0,0,0,0,0,0,0,0
  456. .byte '~,13,0
  457. .byte 0,0,0,0,0,0,0,0,0,0,0
  458. .byte 0,0
  459. .byte 0,0,0,0,0,0,0,0,0,0,0
  460. .byte 0,0,0,0 /* 36-39 */
  461. .fill 16,1,0 /* 3A-49 */
  462. .byte 0,0,0,0,0 /* 4A-4E */
  463. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  464. .byte '|
  465. .fill 10,1,0
  467. #elif defined(KBD_GR)
  469. key_map:
  470. .byte 0,27
  471. .ascii "1234567890\'"
  472. .byte 127,9
  473. .ascii "qwertzuiop@+"
  474. .byte 13,0
  475. .ascii "asdfghjkl[]^"
  476. .byte 0,'#
  477. .ascii "yxcvbnm,.-"
  478. .byte 0,'*,0,32 /* 36-39 */
  479. .fill 16,1,0 /* 3A-49 */
  480. .byte '-,0,0,0,'+ /* 4A-4E */
  481. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  482. .byte '<
  483. .fill 10,1,0
  485. shift_map:
  486. .byte 0,27
  487. .ascii "!"#$%&/()=?`"
  488. .byte 127,9
  489. .ascii "QWERTZUIOP\*"
  490. .byte 13,0
  491. .ascii "ASDFGHJKL{}~"
  492. .byte 0,''
  493. .ascii "YXCVBNM;:_"
  494. .byte 0,'*,0,32 /* 36-39 */
  495. .fill 16,1,0 /* 3A-49 */
  496. .byte '-,0,0,0,'+ /* 4A-4E */
  497. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  498. .byte '>
  499. .fill 10,1,0
  501. alt_map:
  502. .byte 0,0
  503. .ascii "@${[]}\"
  504. .byte 0,0
  505. .byte '@,0,0,0,0,0,0,0,0,0,0
  506. .byte '~,13,0
  507. .byte 0,0,0,0,0,0,0,0,0,0,0
  508. .byte 0,0
  509. .byte 0,0,0,0,0,0,0,0,0,0,0
  510. .byte 0,0,0,0 /* 36-39 */
  511. .fill 16,1,0 /* 3A-49 */
  512. .byte 0,0,0,0,0 /* 4A-4E */
  513. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  514. .byte '|
  515. .fill 10,1,0
  517. #elif defined(KBD_FR)
  519. key_map:
  520. .byte 0,27
  521. .ascii "&{"'(-}_/@)="
  522. .byte 127,9
  523. .ascii "azertyuiop^$"
  524. .byte 13,0
  525. .ascii "qsdfghjklm|"
  526. .byte '`,0,42 /* coin sup gauche, don't know, [*|mu] */
  527. .ascii "wxcvbn,;:!"
  528. .byte 0,'*,0,32 /* 36-39 */
  529. .fill 16,1,0 /* 3A-49 */
  530. .byte '-,0,0,0,'+ /* 4A-4E */
  531. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  532. .byte '<
  533. .fill 10,1,0
  535. shift_map:
  536. .byte 0,27
  537. .ascii "1234567890]+"
  538. .byte 127,9
  539. .ascii "AZERTYUIOP<>"
  540. .byte 13,0
  541. .ascii "QSDFGHJKLM%"
  542. .byte '~,0,'#
  543. .ascii "WXCVBN?./\"
  544. .byte 0,'*,0,32 /* 36-39 */
  545. .fill 16,1,0 /* 3A-49 */
  546. .byte '-,0,0,0,'+ /* 4A-4E */
  547. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  548. .byte '>
  549. .fill 10,1,0
  551. alt_map:
  552. .byte 0,0
  553. .ascii "~#{[|`\^@]}"
  554. .byte 0,0
  555. .byte '@,0,0,0,0,0,0,0,0,0,0
  556. .byte '~,13,0
  557. .byte 0,0,0,0,0,0,0,0,0,0,0
  558. .byte 0,0
  559. .byte 0,0,0,0,0,0,0,0,0,0,0
  560. .byte 0,0,0,0 /* 36-39 */
  561. .fill 16,1,0 /* 3A-49 */
  562. .byte 0,0,0,0,0 /* 4A-4E */
  563. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  564. .byte '|
  565. .fill 10,1,0
  567. #elif defined(KBD_DK)
  569. key_map:
  570. .byte 0,27
  571. .ascii "1234567890+'"
  572. .byte 127,9
  573. .ascii "qwertyuiop"
  574. .byte 134,0,13,0 /* This is IBM-PC, change it to latin-1 */
  575. .ascii "asdfghjkl"
  576. .byte 145,155,0,0
  577. .ascii "'zxcvbnm,.-"
  578. .byte 0,'*,0,32 /* 36-39 */
  579. .fill 16,1,0 /* 3A-49 */
  580. .byte '-,0,0,0,'+ /* 4A-4E */
  581. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  582. .byte '<
  583. .fill 10,1,0
  585. shift_map:
  586. .byte 0,27
  587. .ascii "!"#$%&/()=?`"
  588. .byte 127,9
  589. .ascii "QWERTYUIOP"
  590. .byte 143,94,13,0
  591. .ascii "ASDFGHJKL"
  592. .byte 146,157,0,0
  593. .ascii "*ZXCVBNM;:_"
  594. .byte 0,'*,0,32 /* 36-39 */
  595. .fill 16,1,0 /* 3A-49 */
  596. .byte '-,0,0,0,'+ /* 4A-4E */
  597. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  598. .byte '>
  599. .fill 10,1,0
  601. alt_map:
  602. .byte 0,0
  603. .ascii "@${[]}"
  604. .byte '|,0,0
  605. .byte 0,0,0,0,0,0,0,0,0,0,0
  606. .byte '~,13,0
  607. .byte 0,0,0,0,0,0,0,0,0,0,0
  608. .byte 0,0
  609. .byte 0,0,0,0,0,0,0,0,0,0,0
  610. .byte 0,0,0,0 /* 36-39 */
  611. .fill 16,1,0 /* 3A-49 */
  612. .byte 0,0,0,0,0 /* 4A-4E */
  613. .byte 0,0,0,0,0,0,0 /* 4F-55 */
  614. .ascii "\"
  615. .fill 10,1,0
  617. #else
  618. #error "KBD-type not defined"
  619. #endif
  620. /*
  621.  * do_self handles "normal" keys, ie keys that don't change meaning
  622.  * and which have just one character returns.
  623.  */
  624. do_self:
  625. lea alt_map,%ebx
  626. testb $0x20,_kmode /* alt-gr */
  627. jne 1f
  628. lea shift_map,%ebx
  629. testb $0x03,_kmode
  630. jne 1f
  631. lea key_map,%ebx
  632. 1: movb (%ebx,%eax),%al
  633. orb %al,%al
  634. je none
  635. testb $0x4c,_kmode /* ctrl or caps */
  636. je 2f
  637. cmpb $'a,%al
  638. jb 2f
  639. cmpb $'},%al
  640. ja 2f
  641. subb $32,%al
  642. 2: testb $0x0c,_kmode /* ctrl */
  643. je 3f
  644. cmpb $64,%al
  645. jb 3f
  646. cmpb $64+32,%al
  647. jae 3f
  648. subb $64,%al
  649. 3: testb $0x10,_kmode /* left alt */
  650. je 4f
  651. orb $0x80,%al
  652. 4: andl $0xff,%eax
  653. xorl %ebx,%ebx
  654. call put_queue
  655. none: ret
  657. /*
  658.  * slash and star have routines of their own, as a 'E0h' before
  659.  * the scan code for slash means that the numeric keypad
  660.  * slash was pushed.
  661.  */
  662. slash: cmpb $1,e0
  663. jne do_self
  664. cmpb $1,_kapplic
  665. jne notmapplic
  666. movw $'Q,%ax
  667. jmp applkey
  669. notmapplic:
  670. movl $'/,%eax
  671. xorl %ebx,%ebx
  672. jmp put_queue
  674. star: cmpb $1,_kapplic
  675. jne do_self
  676. movw $'R,%ax
  677. jmp applkey
  679. notsapplic:
  680. movl $'*,%eax
  681. xorl %ebx,%ebx
  682. jmp put_queue
  684. enter: cmpb $1,e0
  685. jne do_self
  686. cmpb $1,_kapplic
  687. jne do_self
  688. movw $'M,%ax
  689. jmp applkey
  691. minus: cmpb $1,_kapplic
  692. jne do_self
  693. movw $'S,%ax
  694. jmp applkey
  696. plus: cmpb $1,_kapplic
  697. jne do_self
  698. movw $'l,%ax
  699. jmp applkey
  701. /*
  702.  * This table decides which routine to call when a scan-code has been
  703.  * gotten. Most routines just call do_self, or none, depending if
  704.  * they are make or break.
  705.  */
  706. key_table:
  707. .long none,do_self,do_self,do_self /* 00-03 s0 esc 1 2 */
  708. .long do_self,do_self,do_self,do_self /* 04-07 3 4 5 6 */
  709. .long do_self,do_self,do_self,do_self /* 08-0B 7 8 9 0 */
  710. .long do_self,do_self,do_self,do_self /* 0C-0F + ' bs tab */
  711. .long do_self,do_self,do_self,do_self /* 10-13 q w e r */
  712. .long do_self,do_self,do_self,do_self /* 14-17 t y u i */
  713. .long do_self,do_self,do_self,do_self /* 18-1B o p } ^ */
  714. .long enter,ctrl,do_self,do_self /* 1C-1F enter ctrl a s */
  715. .long do_self,do_self,do_self,do_self /* 20-23 d f g h */
  716. .long do_self,do_self,do_self,do_self /* 24-27 j k l | */
  717. .long do_self,do_self,lshift,do_self /* 28-2B { para lshift , */
  718. .long do_self,do_self,do_self,do_self /* 2C-2F z x c v */
  719. .long do_self,do_self,do_self,do_self /* 30-33 b n m , */
  720. .long do_self,slash,rshift,star /* 34-37 . - rshift * */
  721. .long alt,do_self,caps,func /* 38-3B alt sp caps f1 */
  722. .long func,func,func,func /* 3C-3F f2 f3 f4 f5 */
  723. .long func,func,func,func /* 40-43 f6 f7 f8 f9 */
  724. .long func,num,scroll,cursor /* 44-47 f10 num scr home */
  725. .long cursor,cursor,minus,cursor /* 48-4B up pgup - left */
  726. .long cursor,cursor,plus,cursor /* 4C-4F n5 right + end */
  727. .long cursor,cursor,cursor,cursor /* 50-53 dn pgdn ins del */
  728. .long none,none,do_self,func /* 54-57 sysreq ? < f11 */
  729. .long func,none,none,none /* 58-5B f12 ? ? ? */
  730. .long none,none,none,none /* 5C-5F ? ? ? ? */
  731. .long none,none,none,none /* 60-63 ? ? ? ? */
  732. .long none,none,none,none /* 64-67 ? ? ? ? */
  733. .long none,none,none,none /* 68-6B ? ? ? ? */
  734. .long none,none,none,none /* 6C-6F ? ? ? ? */
  735. .long none,none,none,none /* 70-73 ? ? ? ? */
  736. .long none,none,none,none /* 74-77 ? ? ? ? */
  737. .long none,none,none,none /* 78-7B ? ? ? ? */
  738. .long none,none,none,none /* 7C-7F ? ? ? ? */
  739. .long none,none,none,none /* 80-83 ? br br br */
  740. .long none,none,none,none /* 84-87 br br br br */
  741. .long none,none,none,none /* 88-8B br br br br */
  742. .long none,none,none,none /* 8C-8F br br br br */
  743. .long none,none,none,none /* 90-93 br br br br */
  744. .long none,none,none,none /* 94-97 br br br br */
  745. .long none,none,none,none /* 98-9B br br br br */
  746. .long none,unctrl,none,none /* 9C-9F br unctrl br br */
  747. .long none,none,none,none /* A0-A3 br br br br */
  748. .long none,none,none,none /* A4-A7 br br br br */
  749. .long none,none,unlshift,none /* A8-AB br br unlshift br */
  750. .long none,none,none,none /* AC-AF br br br br */
  751. .long none,none,none,none /* B0-B3 br br br br */
  752. .long none,none,unrshift,none /* B4-B7 br br unrshift br */
  753. .long unalt,none,uncaps,none /* B8-BB unalt br uncaps br */
  754. .long none,none,none,none /* BC-BF br br br br */
  755. .long none,none,none,none /* C0-C3 br br br br */
  756. .long none,none,none,none /* C4-C7 br br br br */
  757. .long none,none,none,none /* C8-CB br br br br */
  758. .long none,none,none,none /* CC-CF br br br br */
  759. .long none,none,none,none /* D0-D3 br br br br */
  760. .long none,none,none,none /* D4-D7 br br br br */
  761. .long none,none,none,none /* D8-DB br ? ? ? */
  762. .long none,none,none,none /* DC-DF ? ? ? ? */
  763. .long none,none,none,none /* E0-E3 e0 e1 ? ? */
  764. .long none,none,none,none /* E4-E7 ? ? ? ? */
  765. .long none,none,none,none /* E8-EB ? ? ? ? */
  766. .long none,none,none,none /* EC-EF ? ? ? ? */
  767. .long none,none,none,none /* F0-F3 ? ? ? ? */
  768. .long none,none,none,none /* F4-F7 ? ? ? ? */
  769. .long none,none,none,none /* F8-FB ? ? ? ? */
  770. .long none,none,none,none /* FC-FF ? ? ? ? */
  772. /*
  773.  * kb_wait waits for the keyboard controller buffer to empty.
  774.  */
  775. kb_wait:
  776. pushl %eax
  777. pushl %ebx
  778. movl $10000,%ebx
  779. 1: inb $0x64,%al
  780. testb $0x02,%al
  781. je 2f
  782. decl %ebx
  783. jne 1b
  784. 2: popl %ebx
  785. popl %eax
  786. ret
  788. no_idt:
  789. .long 0,0
  790. /*
  791.  * This routine reboots the machine by asking the keyboard
  792.  * controller to pulse the reset-line low. We try that for a while,
  793.  * and if it doesn't work, we do some other stupid things.
  794.  */
  795. _hard_reset_now:
  796. sti
  797. movl $100,%ebx
  798. 1: call kb_wait
  799. movw $0x1234,0x472 /* don't do memory check */
  800. movb $0xfe,%al /* pulse reset low */
  801. outb %al,$0x64
  802. decl %ebx
  803. jne 1b
  804. lidt no_idt /* zero-length idt: should triple-fault */
  805. jmp _hard_reset_now